Əsrin Proqramlaşdırma dili

Müasir proqramlaşdırma dillərini funksiyalarsız təsəvvür etmək mümkün deyil. Əsrin dilində funksiyalar dəstəklənir. Parametr ötürülmə, qiymət qaytarılma və rekursiv çağrılma kimi imknalar hazırki buraxılışda realizə olunub. Parametr ötürmə hazırki buraxılışda ancaq qiymətə görə mümkündür. Bundan əlavə hazırki buraxılışda yalnız standart tiplərdən parametr ötürülməsi və nəticə qaytarılması dəstəklənir. Funksiyalara ünvana görə parametr ötürülməsi növbəti buraxılışlarda əsas prioritet məsələlərdən olacaq.

Əsrin dilində funksiya tərtib etmək üçün funksiya açar sözündən istifadə olunur:

funksiya f () {
   
  xaricet("f funksiyasi \y");
   
}
   
f();

Nəticə

f funksiyasi

Əvvəlcə funksiya açar sözünü yazırıq, daha sonra funksiyanın adını qeyd edirik və mötərizələr daxilində funksiyanın parametrlərini yazırıq. Əgər funksiya heç bir parametr qəbul etmirsə onda mötərizələrin içinə heçnə yazmırıq. Daha sonra isə fiqurlu mötərizələr içində funksiyanın dəyişənlər və kod hissələrini tərtib edirik.
Aşağıdakı kod funksiyalardan istifadə etməklə ekranda cərgə çap edir.

tam x[10][10], k , j;

funksiya cerge_cap ( ) {
        
   say (k 1 10){
      say (j 1 10)
        xaricet(x[k][j] , " ");
	  xaricet("\y");
    }
}
           
//cergeye qiymetler menimsedek
say (k 1 10)
   say (j 1 10)
     x[k][j] = 100 + k*j;

// cerge_cap funksiyasindan istifade etmekle
// x cergesini cap ededk
cerge_cap();

Əgər bu kodu icra eləsək aşağıdakı nəticəni verər:

101 102 103 104 105 106 107 108 109 110
102 104 106 108 110 112 114 116 118 120
103 106 109 112 115 118 121 124 127 130
104 108 112 116 120 124 128 132 136 140
105 110 115 120 125 130 135 140 145 150
106 112 118 124 130 136 142 148 154 160
107 114 121 128 135 142 149 156 163 170
108 116 124 132 140 148 156 164 172 180
109 118 127 136 145 154 163 172 181 190
110 120 130 140 150 160 170 180 190 200

Aşağıdakı kodda İki ədədin cəmini hesablayan cem adli funksiya tərtib olunur və bu funksiyadan istifadə etməklə müxtəlif ədədlərin cəmi hesablanır.

funksiya cem ( tam x, tam y){

  qaytar x + y;

}

tam x,y, z;
  
//sonsuz dovre giririk
// 0 0 -son
neqederki( 1==1 ) {
    
  xaricet("Iki eded daxil edin(0 0 -son).\y");
  daxilet(x,y);
    
  eger (x == 0 ve y==0 )
    dayan;
      
  z = cem(x,y);
  xaricet("cem(",x,",",y,") = ", z, "\y");
    
}

Əgər bu kodu icra eləsək aşağıdakı nəticəni verər:

Iki eded daxil edin(0 0 -son).
2 45
cem(2,45) = 47
Iki eded daxil edin(0 0 -son).
67 8
cem(67,8) = 75
Iki eded daxil edin(0 0 -son).
0 0

Funksiyalardan istifadəyə aid digər proqram nümunəsinə baxaq.

//cergenin elementlerini daxil etmek ucun funksiya
funksiya  crg_daxilet ( ){ 
 
   tam i;  
   xaricet("10 eded daxil edin \y"); 
   
   say  (i 1 10)
     daxilet(x[i]); 
    
   }

//cergenin elementlerini xaric etmek ucun funksiya   
 funksiya  crg_capet ( ){
 
   tam i; 
   
   say  (i 1 10) 
     xaricet(x[i], " "); 
     
   xaricet("\y");
} 

//cergenin elementlerini artan sirada duzmek ucun funksiya
funksiya  crg_artan ( ){
 tam i,j, mvq; 
 
 say  (i 1 10)
   say  (j i 10) 
     eger  (x[i] > x[j]){
       mvq = x[i]; 
       x[i] = x[j]; 
       x[j] = mvq; 
     } 
 }
       
//cergenin elementlerini azlan sirada duzmek ucun funksiya       
 funksiya  crg_azalan ( ){ 
 
  tam i,j, mvq; 
  
  say  (i 1 10)
   say  (j i 10) 
     eger  (x[i] < x[j]){
       mvq = x[i]; 
       x[i] = x[j]; 
       x[j] = mvq; 
     }
 }
 
 //cergenin elementlerini artan sirada duz ve xaric et
 //mufaviq funksiya cagimaqla
  funksiya  artan(){

    crg_artan(); 
    xaricet("Cergenin elementleri artan sirada\y"); 
    crg_capet(); 
 
 } 
 
 //cergenin elementlerini azalan sirada duz ve xaric et
 //mufaviq funksiya cagimaqla
  funksiya  azalan(){
  
    crg_azalan(); 
    xaricet("Cergenin elementleri azalan sirada\y"); 
    crg_capet(); 
	
  }
 
  tam x[10];  
 
  crg_daxilet(); 
  artan(); 
  azalan();

Nəticə:

10 eded daxil edin
12 34 5 67 8 0 90 23 54 66
Cergenin elementleri artan sirada
0 5 8 12 23 34 54 66 67 90
Cergenin elementleri azalan sirada
90 67 66 54 34 23 12 8 5 0